Item talk:Q169182
iSAID started as its own application and set of processes to produce usable linked open data from disparate and often messy source material scattered on the USGS web and in specialized catalogs. iSAID components remain their own deployable software package in Python with the results of processing producing entities and claims within the GeoKB. This page presents the logical queries that return what can be considered "iSAID data."
These data are pulled into other applications for presentation and analysis. A strategy that can be employed for keeping information up to date is to use the schema:dateModified property that indicates when the underlying page for an item was last modified. This will include any updates to the item's statements, including labels, descriptions, and aliases.
People
iSAID assembles records for people from a routine scrape of the USGS staff profile inventory along with examining ORCID references for authors from the USGS Publications Warehouse Catalog, USGS Science Data Catalog, and USGS Model Catalog (not all staff elect to create and maintain staff profiles, but all authors and contributors to USGS products must be identified with an ORCID identifier).
The following are logical queries to obtain personnel records.
People employed by USGS
The GeoKB uses an employed by claim to indicate that a person is or was "employed" by the USGS. We use employed liberally to mean affiliated with but distinguish this in the model from a person's individual specific USGS organization affiliations. Employed could mean volunteer or contract employment as well as Federal FTE employment. The GeoKB uses a point in time qualifier on employed by claims indicating the last time we ran a process to verify that a person was "on USGS roles."
There is no publicly available information online as to the current employment status of a staff person discovered through the staff profiles or ORCID records, the two ways that person entities are instantiated in the GeoKB. We have to rely on staff profiles disappearing or, in some cases, being "annotated" with a "former employee" statement. This is reflected in an "end time" qualifier placed on the USGS as employer claims using the special "UNKNOWN VALUE" type. This indicates that we know the employment status ended but not exactly when that occurred.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX p: <https://geokb.wikibase.cloud/prop/>
PREFIX pq: <https://geokb.wikibase.cloud/prop/qualifier/>
SELECT ?item ?itemLabel ?itemAltLabel ?itemDescription ?orcid ?email ?url ?end_time ?dateModified
WHERE {
?item wdt:P107 wd:Q44210 ; # Employed by the USGS
p:P107 ?emp_statement ;
schema:dateModified ?dateModified . # Pull dateModified to support subsequent update queries
OPTIONAL {
?emp_statement pq:P61 ?end_time . # Any value here indicates that employment status ended at some point
}
OPTIONAL {
?item wdt:P106 ?orcid .
}
OPTIONAL {
?item wdt:P109 ?email .
}
OPTIONAL {
?item wdt:P145 ?url .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
Updates
In a scenario where the GeoKB is being used as a source to keep an alternate representation of this information maintained, the previous query can be run with a filter on dateModified using the last update in a "foreign" table to pull new and updated items.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX p: <https://geokb.wikibase.cloud/prop/>
PREFIX pq: <https://geokb.wikibase.cloud/prop/qualifier/>
SELECT ?item ?itemLabel ?itemAltLabel ?itemDescription ?orcid ?email ?url ?end_time ?dateModified
WHERE {
?item wdt:P107 wd:Q44210 ; # Employed by the USGS
p:P107 ?emp_statement ;
schema:dateModified ?dateModified . # Pull dateModified to support subsequent update queries
OPTIONAL {
?emp_statement pq:P61 ?end_time . # Any value here indicates that employment status ended at some point
}
OPTIONAL {
?item wdt:P106 ?orcid .
}
OPTIONAL {
?item wdt:P109 ?email .
}
OPTIONAL {
?item wdt:P145 ?url .
}
FILTER (?dateModified > "2024-07-01T00:00:00Z"^^xsd:dateTime)
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
All People
The GeoKB also contains records for thousands of additional people who are publicly listed collaborators with USGS, most as coauthors on publications. One approach in pulling data for analysis can be to use the following open query that pulls all person entities with optional information on employer and affiliations.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX p: <https://geokb.wikibase.cloud/prop/>
PREFIX pq: <https://geokb.wikibase.cloud/prop/qualifier/>
SELECT ?person ?personLabel ?personDescription
?employer ?employerLabel ?employer_pit ?employer_start_time ?employer_end_time
?employer_type ?employer_typeLabel
?affiliation ?affiliationLabel ?affiliation_pit
WHERE {
?person wdt:P1 wd:Q3 .
OPTIONAL {
?person wdt:P107 ?employer ;
p:P107 ?employer_statement .
?employer wdt:P1 ?employer_type .
OPTIONAL {
?employer_statement pq:P110 ?employer_pit .
}
OPTIONAL {
?employer_statement pq:P60 ?employer_start_time .
}
OPTIONAL {
?employer_statement pq:P61 ?employer_end_time .
}
}
OPTIONAL {
?person wdt:P108 ?affiliation ;
p:P108 ?affiliation_statement .
OPTIONAL {
?affiliation_statement pq:P110 ?affiliation_pit .
}
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Organizational Affiliations
Person entities have a direct "is affiliated with" claim for the immediate organizational unit that is listed with them in their USGS staff profile. The URLs for these entities are resolved to the "official website" from the USGS organizational representation in the GeoKB. Some personnel have more than one direct affiliation (reflected in the query result below showing the same person on multiple rows with their affiliations).
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?person ?personLabel ?affiliation ?affiliationLabel
WHERE {
?person wdt:P107 wd:Q44210 ;
wdt:P108 ?affiliation .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Regional Affiliation
USGS "line offices" (e.g., Science Centers) are organized into a geographic region structure that is represented in the GeoKB through "is subsidiary of" claims. Some staff work directly for Regions while most others are indirectly associated with Regions through the subsidiary relationship. These two can be combined to produce a result of people connected to Regions in the following query.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?person ?personLabel ?region ?regionLabel
WHERE {
{
?person wdt:P108 ?region .
?region wdt:P1 wd:Q50866 .
} UNION {
?person wdt:P108 ?affiliation .
?affiliation wdt:P190* ?region .
?region wdt:P1 wd:Q50866 .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Occupations
The text description for personnel (included in the previous query) contains a combination of the title that someone used for themselves via the Staff Profile system or sometimes from their ORCID record combined with the latest organizational affiliation. This helps in finding a person via search and disambiguating similar names. The processing run through the iSAID code attempts to link textual job titles to occupational classes/items within the GeoKB. A person can have multiple linked occupations (e.g., someone listing "Supervisory Hydrologist" as their job title will be linked to both hydrologist and supervisor as distinct occupations). A title such as "Supervisory Hydrologist" does happen to relate closely to U.S. Office of Management and Budget job classifications, but there is no direct linkage to those classes because we are relying on public information from web sites.
From a query and data assembly standpoint, it may be easier to query out occupation information separately, though it can be included in the previous SPARQL query.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX p: <https://geokb.wikibase.cloud/prop/>
PREFIX pq: <https://geokb.wikibase.cloud/prop/qualifier/>
SELECT ?person ?personLabel
?occupation ?occupationLabel ?occupation_pit
WHERE {
?person wdt:P107 wd:Q44210 ;
wdt:P150 ?occupation ;
p:P150 ?occupation_statement .
OPTIONAL {
?occupation_statement pq:P110 ?occupation_pit .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
What people know about
A major driver for iSAID was to get down to the best possible characterization of what our people in the USGS know about and the skills they practice. This comes from a combination of what people assert about themselves through things like the USGS Staff Profile system's "Expertise Dashboard," resulting in a set of terms on staff profile pages, and the concepts/terms associated with the publications, datasets, and other products people contribute to. The latter comes from a combination of direct terms associated as keywords in product metadata along with experimental AI-assisted text processing. This all results in a set of generalized "knows about" claims on person entities, that are also best queried separately and then assembled into various usable forms for analysis.
The major work here is in linking what are almost always basic text strings to something tangible and organized into the GeoKB as real entities. Most knows about claims fall into the classification of academic disciplines, but some may be found elsewhere in the GeoKB ontology.
There are many thousands of knows about claims, particularly since we began processing OpenAlex concepts, so you may need to run several SPARQL queries with an offset in order to pull the entire set. It may also be useful to explore the classification more thoroughly than the single subclassOf statement included in the query below for various types of graph-based analyses. Aliases and descriptions on knows about concepts may also prove useful in some cases.
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?person ?personLabel
?knowsAbout ?knowsAboutLabel
?subclassOf ?subclassOfLabel
WHERE {
?person wdt:P203 ?knowsAbout .
?knowsAbout wdt:P2 ?subclassOf .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Organizations
The GeoKB contains records of USGS organizational units and the relationships between them all derived from the USGS web's presentations of the USGS as an institution. While there are other internal sources and codes that could prove useful, we have not incorporated those non-public sources here.
Organizations and relationships
The following query pulls the basic information on USGS organizational units and their connections to one another through the "is subsidiary of" claims. The URLs listed as official website claims are the direct source for the best available public information on these organizational units.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?org ?orgLabel ?instanceOf ?instanceOfLabel
?url ?subsidiaryOf ?subsidiaryOfLabel ?dateModified
WHERE {
?org wdt:P1/wdt:P2* wd:Q50862;
wdt:P1 ?instanceOf ;
schema:dateModified ?dateModified .
OPTIONAL {
?org wdt:P145 ?url .
}
OPTIONAL {
?org wdt:P190 ?subsidiaryOf .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Personnel affiliations
The URLs seen in the previous query are found associated with personnel on their staff profile pages and used to create one or more "is affiliated with" claims on person entities. These claims incorporate a point in time qualifier indicating when that information was last found to be current. We do not remove an affiliation claim from a person item once it has been discovered and recorded.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX p: <https://geokb.wikibase.cloud/prop/>
PREFIX pq: <https://geokb.wikibase.cloud/prop/qualifier/>
SELECT ?person ?personLabel ?org ?orgLabel ?pit
WHERE {
?org wdt:P1/wdt:P2* wd:Q50862 .
?person wdt:P108 ?org ;
p:P108 ?affiliation_statement .
?affiliation_statement pq:P110 ?pit .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Products
The Products aspect of iSAID accounts for the largest suite of entities. It is made up of publications (sourced from the USGS Pubs Warehouse), datasets (sourced from the USGS Science Data Catalog), web articles (sourced from scraping the USGS Web via the Science Explorer), and scientific models (sourced from the USGS Model Catalog). These are all works in progress as we hash through how to transform and process what is generally messy and unlinked source content.
This section provides discussion and queries on accessing these different pools of content.
Publications Warehouse
The majority of publication items in the GeoKB are sourced from the USGS Publications Warehouse. Documents are associated with items representing people using author (P102), editor (P115), or compiler (P116) statements, corresponding to the terms used in the Pubs Warehouse. To deal with the large number of items a strategy can be employed to break up the overall dataset into related elements that can be pulled as tables/dataframes and assembled in an optimal way for some other analytical use. The following are logical queries that can be used to pull everything together.
One strategy is to assemble a basic table of publication identifiers and titles, including the dateModified property to be used in subsequent updates. Since the only use of the P114 property for the "USGS Publications Warehouse IndexID" is on items sourced from the USGS Pubs Warehouse, we can use that as our major query parameter to pull those items. The following query pulls all these items into a single table.
Since the GeoKB now has the full slate of all Pubs Warehouse records, that will include many records that cannot be linked to an extant entity representing a person as contributor to the publication. The query below includes a filter that will only get records that have an author, editor, or compiler linkage to an established person entity in the GeoKB.
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX schema: <http://schema.org/>
SELECT ?item ?itemLabel ?instanceOfLabel ?indexId ?date_published ?doi ?dateModified
WHERE {
?item wdt:P114 ?indexId ; # Short-hand way of getting publications since (right now) all pubs come from the Pubs Warehouse source and have an index ID
wdt:P1 ?instanceOf ;
wdt:P7 ?date_published ;
schema:dateModified ?dateModified .
OPTIONAL {
?item wdt:P74 ?doi .
}
FILTER (
EXISTS { ?item wdt:P102 ?author } ||
EXISTS { ?item wdt:P115 ?editor } ||
EXISTS { ?item wdt:P116 ?compiler }
)
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
LIMIT 1000
Pubs Warehouse Updates
Updates to the basic identification of pubs can be done by applying a filter on dateModified using the last dateModified value from a table being synchronized.
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX schema: <http://schema.org/>
SELECT ?item ?itemLabel ?instanceOfLabel ?indexId ?doi ?dateModified
WHERE {
?item wdt:P114 ?indexId ;
wdt:P1 ?instanceOf ;
schema:dateModified ?dateModified .
OPTIONAL {
?item wdt:P74 ?doi .
}
FILTER (?dateModified > "2024-07-01T00:00:00Z"^^xsd:dateTime)
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
Pubs Warehouse Contributors
If another process has been used to build a table of USGS persons, all we need from the Pubs Warehouse items are the QID identifiers for those entities. A union query can be used to assemble a logical set of author, editor, or compiler connections to publication items. By not applying any other complicated logic, this query should pull up to 100000 records or more.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?item ?indexId ?contributor_type ?contributor
WHERE {
{
?item wdt:P114 ?indexId ;
wdt:P102 ?contributor .
BIND ("author" AS ?contributor_type)
} UNION {
?item wdt:P114 ?indexId ;
wdt:P115 ?contributor .
BIND ("editor" AS ?contributor_type)
} UNION {
?item wdt:P114 ?indexId ;
wdt:P116 ?contributor .
BIND ("compiler" AS ?contributor_type)
}
}
Pubs Warehouse Places
Some of the place tag information from the Pubs Warehouse has been resolved to linkable items representing places in the GeoKB. More work is ongoing to model, organize, and resolve other place names such as river basins and others of potentially more interest than the more general country, state, county items currently in place. Not all place tags in Pubs Warehouse items have been resolved, even in these higher-level categories, due to ambiguity (e.g., county names not found in the states listed for the same items). The following query will pull all resolved "addresses place" claims for Pubs Warehouse items. Additional statements from place items could be pulled in as needed (e.g., hierarchical relationships, etc.), but those may be best handled in a related table of some kind.
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?item ?indexId ?place ?placeLabel
WHERE {
?item wdt:P114 ?indexId ;
wdt:P95 ?place .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Pubs Warehouse Subjects
Only a small number of "addresses subject" claims have been handled so far in the GeoKB. We are currently doing topic modeling work with OpenAlex terms with our initial focus on establishing "knows about" claims for authors/contributors to creative works. The pool of available linked subject matter will increase dramatically once we finish working through the ~20K underlying unique keywords from OpenAlex and apply those to publication items. We are also experimenting with a generated knowledge graph approach from processing full texts that shows promise but will take time to develop.
The following query is similar to the place query and pulls the basic identifiers/labels for all addresses subject claims on Pubs Warehouse items.
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?item ?indexId ?subject ?subjectLabel
WHERE {
?item wdt:P114 ?indexId ;
wdt:P94 ?subject .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Web Articles
Additional "products" are introduced to the GeoKB from the "/science/" articles on the USGS Web Site. These are scraped from the Science Explorer, transformed to a compliant schema.org structure, and linked to existing entities within the GeoKB. Person points of contact on the pages are linked as authors. Organization entities from the "by line" are linked as "owner." Topics that can be resolved to the set of keywords are linked as "addresses subject" claims. Additional work will be done with the keywords and texts over time to add additional subjects and geographic places.
As with other queries described here, this will pull all the pertinent details in a flat table structure that can be parsed out into a desired structure for analysis or for driving applications.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?itemDescription ?url
?usgs_org ?usgs_orgLabel
?author ?authorLabel
?addressesSubject ?addressesSubjectLabel
WHERE {
?item wdt:P1 wd:Q226753 ; # "web page"
wdt:P136 ?url .
OPTIONAL {
?item wdt:P112 ?usgs_org .
}
OPTIONAL {
?item wdt:P102 ?author .
}
OPTIONAL {
?item wdt:P94 ?addressesSubject .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
Data Releases
We are slowly pulling in records for USGS data assets, starting with the official data release products. We're still having some technical difficulty working with the Science Data Catalog API and have resorted to using the Datacite repository as our source, concentrating on the 10.5066 DOI identifiers. Full Datacite metadata content is stored in the wiki pages for each data release item. This includes all subjects, including those not yet linked to a "real" entity in the knowledge graph, and abstracts, making the content available in Wikibase full text search.
The following query pulls all items in the GeoKB with DOIs starting with the primary USGS identifier space for official data products.
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?item ?itemLabel ?itemDescription ?doi ?instance_ofLabel
WHERE {
?item wdt:P74 ?doi ;
wdt:P1 ?instance_of .
FILTER (STRSTARTS(STR(?doi), "10.5066"))
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Data Release Authors
The only author linkages organized into the GeoKB for data assets come from those cases where a) "creators" are in the DOI metadata with ORCID identifiers and b) we have a person entity identified with that ORCID. Not all dataset DOI records have ORCID identifiers recorded (something that likely needs to be addressed with some catalog maintenance in the USGS), and not all ORCID-identified dataset contributors are yet recorded in the GeoKB. We will introduce additional ORCID-identified people (often for collaborators from other institutions) from the data asset record into the GeoKB once we come up with a reliable way to identify the affiliations to linkable organizational entities.
The following query pulls authorship for data releases that have been confirmed and recorded. The ORCID identifier can be omitted if not needed.
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?item ?doi ?author ?orcid
WHERE {
?item wdt:P74 ?doi ;
wdt:P102 ?author .
?author wdt:P106 ?orcid .
FILTER (STRSTARTS(STR(?doi), "10.5066"))
}
Data Release Subjects
In processing Datacite records, we attempt to match subjects (keywords) recorded with the records to subject matter classification items within the GeoKB on a simple selective label match process. This produces some number of addresses subject claims that can be accessed with the following query.
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?item ?doi ?subject ?subjectLabel
WHERE {
?item wdt:P74 ?doi ;
wdt:P94 ?subject .
FILTER (STRSTARTS(STR(?doi), "10.5066"))
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
This process does not comprehensively address linking data release items to all the things they could be linked to. The SDC process attempts some additional organization of keyword content from source metadata such as purported USGS Thesaurus terms and geographic place names. However, these still do not point to confirmed entities with some form of persistent resolvable identifier and therefore must be further processed (once we work out the technical difficulties with the SDC services).
Lines of Inquiry
One of the major intended uses for the iSAID work is the conduct of capacity assessments with a Capacity Assessment Framework developed by Olivia Pearman. Capacity for a particular scientific thrust is supported in the GeoKB through the development of a logical ontology of subject matters and other entities that represent a line of inquiry. This is still a developing concept as we work through experimentation with an initial LoI developed for USGS Climate Science. A line of inquiry will consist of some suite of linked items representing scientific subject matter that is in the set of classification items in the GeoKB, places and geographic features, and other items. The LoI ontology is linked to other entities such as people, organizations, products, and projects through addresses subject, addresses place, and uses properties.
Together, these can be used to assemble a logical dataset representing the overall scientific portfolio for a given line of inquiry. While a SPARQL query could be crafted to pull this full dataset together in one operation, the query service in the current Wikibase instance will not support that operation at scale. So, the dataset has to be assembled in parts.
Line of Inquiry Ontology
The following query uses transitive operations to pull together what amounts to a full ontology for a line of inquiry (USGS climate science in this case). These are the full slate of concepts that people, organizations, products, and projects will be connected to in some way. Top level concepts connect directly via part of relationships while others may be connected to those subject matters via other relationships.
If you used previous queries for pulling full data on entities of interest (persons, publications, etc.), including the subject matter claims (via knows about, addresses subject, etc.), then you have the identifiers and labels you will get from this query. This query will then give you how those concepts connect to the higher-level concepts in the line of inquiry ontology.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?loi ?loiLabel
?topic ?topicLabel
?subject ?subjectLabel
WHERE {
?loi wdt:P62 wd:Q160059 . # entity representing the "start" of a line of inquiry that other things are a part of
?topic wdt:P62 ?loi . # entities representing topics that are directly declared as part of the line of inquiry
?subject wdt:P94* ?topic . # subjects that address the topics that are part of the line of inquiry
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
Persons that know about concepts in the Line of Inquiry
Entities representing persons are connected to subject matters that will show up in a line of inquiry via "knows about" claims. These are built from expertise terms where a person asserts that they have some type of expertise in a subject area (where these can be linked to concepts organized into the GeoKB) and via OpenAlex terms assigned to a person (and linked to with ORCID) that are built from the publications record where the person is a contributor to publications with those subject matters.
Note that this query is complex enough to generally throw a timeout error with the SPARQL service and will need to be broken up with limit and offset to pull a full dataset. If you use queries described above to pull a full set of person entities with their knows about claims, then you already have all the data necessary to produce the graph from this query.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?loi ?loiLabel
?topic ?topicLabel
?subject ?subjectLabel
?person ?personLabel
WHERE {
?loi wdt:P62 wd:Q160059 .
?topic wdt:P62 ?loi .
?subject wdt:P94* ?topic . # addresses subject
{
?person wdt:P203 ?topic . # person knows about topic
} UNION {
?person wdt:P203 ?subject . # person knows about subject
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
LIMIT 1000
Publications (documents) that address the Line of Inquiry
Building on the query that pulls the ontology, we can add products that address those subject matters to our dataset. These product-topic/subject relationships may also yield additional person contacts when analyzing the graph. While we could add that connection directly to the query via author/editor/compiler claims (the types of contributors to products), that query cannot execute with the current SPARQL service. It is better to break things out and add them together in another venue.
Note that if you assemble a dataset by pulling all publications via queries in the previous section and include all subjects, then you will have all the data necessary to produce the graph from this query anyway.
PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
SELECT ?loi ?loiLabel
?topic ?topicLabel
?subject ?subjectLabel
?doc ?docLabel
WHERE {
?loi wdt:P62 wd:Q160059 .
?topic wdt:P62 ?loi .
?subject wdt:P94* ?topic . # addresses subject
{
?doc wdt:P1/wdt:P2* wd:Q5 ; # doc is instance of some subclass of document
wdt:P94 ?topic . # and addresses the topic
} UNION {
?doc wdt:P1/wdt:P2* wd:Q5 ; # doc is instance of some subclass of document
wdt:P94 ?subject . # and addresses the subject
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
