Item talk:Q161378

Geologic Time Interval

The GeoKB representation of geologic time generally conforms with the Geoscience Ontology's representation but incorporates only select details from that formal ontology and focuses some attention on ensuring that the GeoKB accurately represents the divisions of geologic time as accepted by the USGS and required for USGS authors. The schema includes a number of conventions:

• Entities are instances of one of the divisions of geologic time (see below) that are classified according to the higher level common core ontologies approach used in the Geoscience Ontology
• Instantiation/type-classification of geologic time interval entities includes "knowledge source" references pointing to items describing the logical source(s) for the concept, providing a simple route to query for time intervals conforming to a particular source of definition
• Same as claims point to URL-type identifiers (most are resolvable) for the entity in another vocabulary. These are not referenced as they are an assertion of sameness/comparability from the GeoKB itself, though these assertions may be backed by content in a source used to instantiate the item.
• From the Geoscience Ontology, the GeoKB does incorporate next and previous intervals along with "time contains" statements to aid in understanding relationships and the overall graph.
• The GeoKB deliberately excludes content on age estimates and the differentiating characteristics of time interval boundaries as the domain of underlying vocabularies and scientific sources. We may elect to incorporate some of this information along with useful comments and original source information into item discussion pages at some point if it proves useful as a local reference.

USGS Divisions of Geologic Time

USGS-authored publications are generally required to only use and refer to divisions of geologic time described in the latest publication describing the geologic time chart according to the USGS Geologic Names Committee. In order to account for this need, the GeoKB incorporates a "knowledge source" reference statement on the instantiation (type classification) claims of time interval entities that trace to the latest publication. The following query can be used to return these entities along with their labels, descriptions, and classification but without other details introduced by either the Geoscience Ontology or the International Chronostratigraphic Chart.

PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX p: <https://geokb.wikibase.cloud/prop/>

SELECT ?item ?itemLabel ?itemDescription ?item_class ?item_classLabel
WHERE {
  ?item_class wdt:P2 wd:Q161378 .
  ?item wdt:P1 ?item_class ;
       p:P1 ?instance_of_statement .
  ?instance_of_statement prov:wasDerivedFrom ?ref .
  ?ref ?rp ?ro .
  FILTER CONTAINS(STR(?ro), "Q57435")
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . } 
}

Try it!

Type Classification for Geologic Time

PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>

SELECT ?age_class ?age_classLabel ?age_classDescription
WHERE {
  ?age_class wdt:P2 wd:Q161378 .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . } 
}

Try it!

Full Geologic Time Graph

The following query pulls all geologic time intervals regardless of source but includes the reference items on the instantiation claims for use in filtering. It includes the next and previous interval claims along with the time contains claims pulled from the Geoscience Ontology. No grouping is done in the claim in order for the graph connecting all entities to be functional.

PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX p: <https://geokb.wikibase.cloud/prop/>

SELECT ?item ?itemLabel ?itemDescription ?item_class ?item_classLabel
?next_interval ?next_intervalLabel ?previous_interval ?previous_intervalLabel
?time_contains ?time_containsLabel ?ro ?roLabel
WHERE {
  ?item_class wdt:P2 wd:Q161378 .
  ?item wdt:P1 ?item_class ;
       p:P1 ?instance_of_statement .
  OPTIONAL {
    ?item wdt:P161 ?next_interval .
  }
  OPTIONAL {
    ?item wdt:P162 ?previous_interval .
  }
  OPTIONAL {
    ?item wdt:P163 ?time_contains .
  }
  ?instance_of_statement prov:wasDerivedFrom ?ref .
  ?ref ?rp ?ro .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . } 
}

Try it!