Item talk:Q160059

Introduction

Climate plays an important role in where plants, animals, and humans can thrive. As the global climate changes, it threatens the safety and well-being of our communities, our economy, and our natural heritage. The USGS investigates the causes and consequences of climate change. This science is used by decision makers to develop more informed adaptation and mitigation strategies.

The USGS provides policymakers, resource managers, and the public climate science to help guide better decisions for building sustainable resource stewardship across America’s public lands and beyond.

USGS Climate Science Ontology

This GeoKB item serves as a base for a developing ontology that describes and links together the USGS climate science portfolio. The direct "descendents" with a part of relationship to this item provide high-level themes ("scientific lines of inquiry") that group together specific subject matters and scientific methods. These are then directly or indirectly (through deeper level subjects) linked to person entities via knows about claims or to other entities (organizations, projects, products) via addresses subject and uses claims.

Some of the concepts in the USGS climate science ontology were already established in the GeoKB through other sources such as the USGS thesaurus while a number of new concepts have been added. In working through the set of concepts, we have also begun establishing some other same as relationships between direct and related topics to the Global Change Master Directory (GCMD) as organized into the Global Change Information System (GCIS) and the SWEET Ontology.

In order to develop linkages in the graph to entities we want to examine in relation to the USGS climate science topics (e.g., people, organizations, products, and projects), we need to connect the various descriptors and keywords found in metadata about those items sometimes aided by machine learning. In the case of OpenAlex concepts we have begun incorporating, we often have valuable keywords associated with the lowest level concepts that are directly part of these concepts. When we initially ingested the OpenAlex topics, keywords were added to aliases as a basic aid in finding the items through search. In this exercise, we have begun breaking those out into their own entities in the knowledge graph and establishing linkages via addresses subject, addresses place, or uses (e.g., when the object is a research method or technique) predicates.

Themes and Topics

This query can be used to pull the entire set of concepts linked together to make up the USGS climate science ontology.

PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>

SELECT ?loi ?loiLabel ?loiDescription
?topic ?topicLabel ?topicDescription
?subject ?subjectLabel ?subjectDescription
WHERE {
  ?loi wdt:P62 wd:Q160059 . # Highest level grouping concepts representing broad scientific lines of inquiry
  ?topic wdt:P62 ?loi . # Next-level set of research topics and scientific methods directly associated with the lines of inquiry
  {
    ?subject wdt:P94* ?topic . # addresses subject
  } UNION {
    ?subject wdt:P95* ?topic . # addresses place
  } UNION {
    ?subject wdt:P208* ?topic . # uses
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}

Try it!

Entity Relationships

Other entities (persons, organizations, products, and projects) are linked into the climate science ontology via "knows about" claims (in the case of persons) and "addresses subject," "addresses place," and/or "uses" claims in the case of other types of entities. The following query builds on the previous query to return person entities linked into the climate change ontology. Because this is ultimately a very large result set, using limit and offset in SPARQL will aid in pulling a full dataset for analysis.

PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>

SELECT ?loi ?loiLabel
?topic ?topicLabel
?subject ?subjectLabel
?person ?personLabel
WHERE {
  ?loi wdt:P62 wd:Q160059 .
  ?topic wdt:P62 ?loi .
  {
    ?subject wdt:P94* ?topic . # addresses subject
  } UNION {
    ?subject wdt:P95* ?topic . # addresses place
  } UNION {
    ?subject wdt:P208* ?topic . # uses
  }
  {
    ?person wdt:P203 ?topic .
  } UNION {
    ?person wdt:P203 ?subject .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
}
LIMIT 1000

Try it!