Item talk:Q152682

The concept of "mineral resource assessment" is an important one as it is one of the fundamental mandates in the USGS mission. It is also a somewhat elusive concept to fully define, but we need to put some thought into it as we look to use it in the GeoKB.

Initial Classification

This item fits within a classification scheme designed to describe specific scientific methods as an entity type. The full classification can be retrieved and visualized with the following query.

PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?subclass ?subclassLabel
WHERE {
  wd:Q152682 wdt:P2* ?item .
  ?item wdt:P2* wd:Q2 .
  OPTIONAL {
    ?item wdt:P2 ?subclass .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
ORDER BY ?item

Try it!

Mineral Resource Assessment Publications

The following query is designed to assemble a usable table of those articles/reports that have been classified as mineral resource assessments. It uses the same logic used in the formatter URL property on the DOI and USGS Pubs Warehouse ID properties to build clickable links.

PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel 
(YEAR(?pub_date) AS ?year) 
(CONCAT("https://doi.org/", ?doi) AS ?doi_link)
(CONCAT("https://pubs.er.usgs.gov/publication/", ?indexId) AS ?usgs_link)
WHERE {
  ?item wdt:P1 wd:Q152682 . # item is an instance of "mineral resource assessment"
  OPTIONAL {
    ?item wdt:P7 ?pub_date .
  }
  OPTIONAL {
    ?item wdt:P74 ?doi .
  }
  OPTIONAL {
    ?item wdt:P114 ?indexId .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

Try it!