Item talk:Q24

Mineral Material

This is the top level of the class hierarchy for minerals.

Sources

The two main sources we processed for foundational mineral identification and a few details include Mindat and the Geoscience Ontology (GSO). The former provides a rich set of mineral characteristics and mineralogy information. The latter provides additional context and surrounding explicit semantics on how minerals relate to other aspects of geoscience. Individual mineral classes have same as links to one or both of the corresponding entity in Mindat and/or the GSO to both indicate that we're talking about the same mineral species and provide an avenue to get additional information.

Note: The IRI values for mineral classes from the GSO are unique and accurate to the source but do not currently resolve properly via the w3id.org URLs assigned. This is an issue we will work to correct. For now, linking through a browser will land on a web page that will need to be further navigated.

Scope

Initially at least, we did not incorporate all mineral species into the GeoKB but only those that are mostly associated with the economic geology focus of the USGS Mineral Resource Assessment Program. We may revisit this decision through time as other linkages necessitate. The software code used to do most of the work in organizing Mindat and GSO source content used the set of mineral material names from the Mineral Resource Data System as a reasonably comprehensive set to start. We did pull in additional mineral names based on the relationship with mineral groups, varieties, and synonyms starting from MRDS name linkages.

Schema Decisions

Organizing knowledge within the Wikibase framework is similar to formal ontologies in OWL but not exactly the same. We patterned the GeoKB representation for mineral materials on the GSO source in terms of higher-level classification.

Class Hierarchy Query

Mineral material is within the same overall hierarchy used in the GSO, aligning with Common Core Ontology and Basic Formal Ontology concepts. It also fits within select aspects from the Wikidata class structure to help create linkages with compatible Wikidata content. The following query retrieves the full class structure up through entity, the origin item in the GeoKB.

PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX wd: <https://geokb.wikibase.cloud/entity/>

SELECT ?item ?itemLabel ?subclass_of ?subclass_ofLabel
WHERE {
  wd:Q24 wdt:P2* ?item .
  ?item wdt:P2 ?subclass_of .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

Try it!

Label, Description, and Aliases

For the most part, primary labels for mineral species, groups, mixtures, etc. come directly from primary names used in Mindat. These may or may not be where we find an exact match to mineral names as referenced in USGS data sources, but they were deemed to be a reasonable starting point. We may revisit primary labels through time in practical use.

Alternate labels include many other name variants useful as finding aids and establishing linkages from various source systems. Most of these come directly from Mindat and include most of the synonyms from that source (including those that have their own Mindat identifiers but are indicated as synonyms for a primary record). We also included the "rruffnameplain" values from GSO when these were not already part of Mindat and the MRDS name if it was slightly different. This approach using the alias part of the Wikibase model simply sets up a big list of terms that a given item can be known by and does not keep track of where those names come from or any other context. We think this is a reasonable enough approach for the time being.

Descriptions are mostly a short statement about what the item is and where it came from. We used the "entrytypetext" information from Mindat (e.g., mineral, variety, etc.) here for a part of the descriptor regardless of how the items are actually classified.

Subclassification

From a basic classification standpoint, we break minerals up into two categories: those that are classified under the Nickel-Strunz classification system and those that are not.

The following query will pull the GeoKB rendition of the Nickle-Strunz V10 classification. This is based on a scrape of the source for the top three aspects of the classification along with the identifiers and labels used in the GSO for the lowest level. In keeping with the OWL-based GSO, mineral items, whether from the GSO or Mindat, are all classes in the GeoKB representation.

There are also cases where rock materials (another subclass of solid geologic material) are included in the class hierarchy with mineral materials based on groupings from the Mindat source.   

PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX wd: <https://geokb.wikibase.cloud/entity/>

SELECT ?item ?itemLabel ?strunz_code ?subclass_of ?subclass_ofLabel
WHERE {
  ?item wdt:P2* wd:Q161395 ;
        wdt:P2 ?subclass_of ;
        wdt:P168 ?strunz_code .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

Try it!

The following query pulls the unclassified mineral materials and their same as links.

PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX wd: <https://geokb.wikibase.cloud/entity/>

SELECT ?item ?itemLabel (GROUP_CONCAT(?same_as; separator=', ') as ?same_as_links )
WHERE {
  ?item wdt:P2* wd:Q162997 ;
        wdt:P84 ?same_as .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}
GROUP BY ?item ?itemLabel

Try it!

Variety Of and Member Of

In addition to the class hierarchy structure, mineral material entities are also further characterized and linked to one another through the variety and group member relationships captured in Mindat. There is also a "structuralgroup" property included in the GSO minerals module, but this is a label property and not an identifier. We elected to use the explicit identifier-based relationship from Mindat to capture these relationships.

The following query returns the logical graph of mineral material group relationships.

PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX wd: <https://geokb.wikibase.cloud/entity/>

SELECT ?item ?itemLabel 
  ?member_of ?member_ofLabel 
  ?has_member ?has_memberLabel
WHERE {
  {
    ?item wdt:P2* wd:Q24 ;
          wdt:P164 ?member_of .
  } UNION {
    ?item wdt:P2* wd:Q24 ;
          wdt:P165 ?has_member .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

Try it!

The following query returns the logical graph of varieties.

PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX wd: <https://geokb.wikibase.cloud/entity/>

SELECT ?item ?itemLabel 
?variety_of ?variety_ofLabel 
?has_variety ?has_varietyLabel
WHERE {
  {
    ?item wdt:P2* wd:Q24 ;
          wdt:P166 ?variety_of .
  } UNION {
    ?item wdt:P2* wd:Q24 ;
          wdt:P167 ?has_variety .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

Try it!

Chemical Element Composition

To represent the geochemistry at a high level, we pulled the elements listing from Mindat records (also present in the GSO) and established linkages using the has chemical element property. Chemical elements are also organized into the GeoKB. The following query pulls the graph of minerals and their basic chemical composition.

PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX wd: <https://geokb.wikibase.cloud/entity/>

SELECT ?item ?itemLabel ?has_element ?has_elementLabel
WHERE {
  ?item wdt:P2* wd:Q24 ;
        wdt:P169 ?has_element .
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

Try it!

Additional Content

Underlying source material from Mindat, to which the selective set of mineral material items in the GeoKB are linked, is rich with additional characteristics and detail, some of which may be incorporated here as needed with future use cases. A couple of additional pieces of information from both the Mindat and GSO sources were included on item discussion pages for mineral material classes here.

• Short descriptions from Mindat and comment properties from the GSO
• IMA (from Mindat) and RRUFF (from GSO) chemical formulas
• URL links to WebMineral.com and HandbookOfMineralology.com from GSO