Item talk:Q50862

USGS Organizations

In the GeoKB, we have organized items representing USGS organizational units in the best way possible based on existing public information on the USGS web. The web sites for USGS list the following major organization types:

• Mission Areas
• Programs
• Regions
• Science Centers

The USGS web also has listings for two additional types of "sub-organizations" (Laboratories and Observatories) that are not necessarily fully complete. As with many organizations, USGS organizational units are fluid through time and do not always have persistent, resolvable identifiers that stand the test of time. Older references to organization names may no longer be found online in a reliable form. In the GeoKB, we are attempting to provide a platform where this dynamic can be dealt with and recorded in a way that serves as an enduring reference and an indication of where things change.

Classification

The concept of organization aligns with several different standard ontologies, including FOAF and schema.org. In the GeoKB, we place government organization as a specific subclass of organization and then another subclass of USGS organization. From the USGS organization item, we place subclasses that align with the USGS web public presentation of the USGS organizational structure along with some additional interpretation to help reflect the organizations as presented. The following query assembles the entire classification graph used for USGS organizations in the GeoKB:

PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>
PREFIX wd: <https://geokb.wikibase.cloud/entity/>

SELECT ?item ?itemLabel ?subclass_of ?subclass_ofLabel
WHERE {
  {
    wd:Q50862 wdt:P2* ?item .
    ?item wdt:P2 ?subclass_of .
  } UNION {
    ?item wdt:P2* wd:Q50862 ;
          wdt:P2 ?subclass_of .
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

Try it!

Names and Identifiers

Organization names change through time. Sometimes, these are particularly significant changes that reflect a fundamental change in organizational structure, form, and function. In other cases, these changes reflect something less substantive where alternate names are essentially a simpler change in identifier. In the former case, we attempt to reflect this dynamic with a new entity in the GeoKB and a relationship to a former entity. In the latter case, we simply use alternate labels that allow an item to be discovered or referred to using a former name that may still be in use in some cases.

There is no single persistent identifier system for all USGS organizations. While there are internal codes used in business management systems, these do not serve the purpose of uniquely identifying an organizational unit through time. Some USGS organizational units do have identifiers such as DUNS numbers as granting institutions or Research Organization Registry identifiers.

The following query retrieves items with ROR identifiers, which may prove over time to be a reasonable approach for USGS to follow in persistently identifying its organizational units through an external resolver system.

PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?ror ?ror_url
WHERE {
  ?item wdt:P193 ?ror .
  BIND (CONCAT("https://ror.org/", STR(?ror)) AS ?ror_url)
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

Try it!

All USGS Organizations

The GeoKB can prove a useful tool in reconciling USGS organization names to other identifiers. Though non-persistent and unstable through time, URLs for organizations could prove useful in some cases and are included in the GeoKB as reference URL claims (P31). The GeoKB can be used as a reconciliation service for something like a spreadsheet of records processed through OpenRefine. The following query will return all USGS organizations, including alternate labels (which includes things like acronyms), in a format that can be suitable for lookup and name resolution purposes.

PREFIX wd: <https://geokb.wikibase.cloud/entity/>
PREFIX wdt: <https://geokb.wikibase.cloud/prop/direct/>

SELECT ?item ?itemLabel ?item_alt_label ?instance_ofLabel ?url
WHERE {
  ?org_types wdt:P2 wd:Q50862 . # Gets subclasses of USGS organization
  ?item wdt:P1 ?org_types . # Gets items in those classes
  ?item wdt:P1 ?instance_of . # Gets the individual instance of classification
  OPTIONAL {
    ?item skos:altLabel ?item_alt_label . # Retrieves alternate labels into separate rows
    FILTER (lang(?item_alt_label)='en')
  }
  OPTIONAL {
    ?item wdt:P31 ?url . # Get all reference URLs when available
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en" . }
}

Try it!